      SUBROUTINE DUNNEPAR(SCLNCL,ADU,CNH3N,CNH3CH,RKBN,RKBCH,RKTN,RKTCH, &
                          DUALFA,PRION,TA,RH,RHOA,H2SO4,NH3,YSCALE, &
                          YM3TOCM3,YSDUNNE,ILGA,LEVA)
!
      USE SDPARM
      USE SDPHYS
      USE FPDEF
!
      IMPLICIT REAL (A-H,O-Z), INTEGER (I-N)
!
      REAL, INTENT(OUT), DIMENSION(20) :: ADU
      REAL(R8), INTENT(OUT), DIMENSION(ILGA,LEVA) :: CNH3N,CNH3CH,RKBN, &
                                                     RKBCH,RKTN,RKTCH, &
                                                     DUALFA,PRION,SCLNCL
      REAL(R8), INTENT(IN), DIMENSION(ILGA,LEVA) :: H2SO4
      REAL, INTENT(IN), DIMENSION(ILGA,LEVA) :: TA,RH,RHOA,NH3
      REAL, INTENT(IN) :: YSCALE
      INTEGER, INTENT(IN) :: ILGA,LEVA
      REAL, DIMENSION(:,:), ALLOCATABLE :: TEMP,AIRD,NH3P,H2SO4P
      REAL, INTENT(OUT) :: YM3TOCM3
      REAL, INTENT(OUT) :: YSDUNNE
!
!-----------------------------------------------------------------------
!
      YM3TOCM3=1.E+06
      YSDUNNE=1.E-06
!
!     * ALLOCATE WORK ARRAYS.
!
      ALLOCATE(TEMP(ILGA,LEVA))
      ALLOCATE(AIRD(ILGA,LEVA))
      ALLOCATE(NH3P(ILGA,LEVA))
      ALLOCATE(H2SO4P(ILGA,LEVA))
!
!     * COLLECTION OF PARAMETERS IN NUCLEATION PARAMETERIZATION.
!
      ADU = (/3.95451,9.702973,12.62259,-0.007066146,182.4495,1.203451, &
             -4.188065,9.003471,636801.6,2.891024,-11.48166,25.49469, &
              0.1810722,3.373738,4.071246,-23.8002,37.03029,0.227413, &
              206.9792,3.138719 /)
      TEMP=TA/1000.
!
!     * NUMBER DENSITY OF AIR (MOLECULES/CM3).
!
      AIRD=RHOA*AVO/WA/YM3TOCM3
!
!     * SCALE AMMONIA CONCENTRATION TO CONVERT FROM VOLUME MIXING RATIO
!     * TO 10E6*MOLECULES/CM3
!
      NH3P=NH3*AIRD*YSDUNNE
!
!     * SCALE SULPHURIC ACID CONCENTRATION TO CONVERT FROM FMOL/M3 
!     * TO 10E6*MOLECULES/CM3
!
      H2SO4P=H2SO4*(AVO/(YSCALE*YM3TOCM3))*YSDUNNE
!
!     * COEFFICIENTS IN DUNNE'S PARAMETERIZATION.
!
      CNH3N=ADU(9) * (NH3P**(1-ADU(8))) &
               / (1 + ADU(9) * (NH3P**(1-ADU(8)))*(H2SO4P**ADU(10)) )
      CNH3CH=ADU(19) * (NH3P**(1-ADU(15))) &
               / (1 + ADU(19) * (NH3P**(1-ADU(15)))*(H2SO4P**ADU(20)) )
      RKBN=EXP(ADU(2) - EXP(ADU(3)*(TEMP-ADU(4))))
      RKBCH=EXP(ADU(11) - EXP(ADU(12)*(TEMP-ADU(13))))  
      RKTN=(EXP(ADU(5) - EXP(ADU(6)*(TEMP-ADU(7)))))*CNH3N* &
               (NH3P / 100.)**ADU(8) * 100**ADU(8)
      RKTCH=(EXP(ADU(16)-EXP(ADU(17)*(TEMP-ADU(18)))))*CNH3CH* &
            (NH3P**ADU(15))    
!
!     * ION-ION RECOMBINATION RATE (BRASSEUR AND CHATTEL).
!
      DUALFA=6.E-08*SQRT(300./TA)+6.E-26*AIRD*(300./TA)**4.
!
!     * ION PRODUCTION RATE (ION PAIRS/CM3/SEC).
!
      PRION=5.
!
!     * NUCLEATION RATE SCALING PARAMETER TO ACCOUNT FOR DEPENDENCY
!     * ON RELATIVE HUMIDITY.
!
      SCLNCL=(1.+1.5*(RH-0.38)+0.045*((RH-0.38)**3)*(TA-208.)**2)
      SCLNCL=MAX(SCLNCL,0.)
!
!     * DEALLOCATE WORK ARRAYS.
!
      DEALLOCATE(TEMP)
      DEALLOCATE(AIRD)
      DEALLOCATE(NH3P)
      DEALLOCATE(H2SO4P)
!
      END SUBROUTINE DUNNEPAR
