      SUBROUTINE OZINT3(OZROW,OZROL,ILG,IL1,IL2,LEVOZ,DELT,
     1                  GMT,IDAY,LDAY)
C
C     * MAY 06/05 - M.LAZARE. NEW VERSION FOR GCM15E ONWARD:
C     *                       - INTERPOLATES IN TERMS OF SECONDS
C     *                         INSTEAD OF TIMESTEPS, TO AVOID
C     *                         ROUNDOFF ERROR WHICH CAME FROM
C     *                         DIVIDING BY TIMESTEP.
C     *                         THIS AROSE FOLLOWING INVESTIGATION
C     *                         BY DAVID PLUMMER.
C     * APR 28/03 - M.LAZARE. PREVIOUS VERSION OZINT2 PRIOR TO GCM15E.
C
C     * OZROW  = OZONE FIELD    FOR PREVIOUS TIMESTEP. 
C     * OZROL  = OZONE FIELD    AT NEXT PHYSICS TIME.
C
C     * ILG    = SIZE OF LONGITUDE LOOP (CHAINED).
C     * IL1    = START OF LONGITUDE LOOP.
C     * IL2    = END   OF LONGITUDE LOOP. 
C     * LEVOZ  = NUMBER OF OZONE LEVELS.
C     * DELT   = MODEL TIMESTEP IN SECONDS. 
C     * GMT    = NUMBER OF SECONDS IN CURRENT DAY.
C     * IDAY   = CURRENT JULIAN DAY.  
C     * LDAY   = DATE OF TARGET OZONE.
C 
C     * MULTI-LEVEL PPMV FOR OZONE.
C
      IMPLICIT REAL   (A-H,O-Z),
     +INTEGER (I-N)                                         

      REAL     OZROW(ILG,LEVOZ),  OZROL(ILG,LEVOZ)
C-------------------------------------------------------------------- 
C     * COMPUTE THE NUMBER OF TIMESTEPS FROM HERE TO MDAY. 
C
      SEC0=REAL(IDAY)*86400. + GMT
C
      FLSEC=REAL(LDAY)*86400. 
      IF(FLSEC.LT.SEC0) FLSEC=FLSEC+365.*86400. 
C
      SECSL=FLSEC-SEC0
C 
C     * GENERAL INTERPOLATION.
C 
      DO 200 L=1,LEVOZ
      DO 200 I=IL1,IL2
        OZROW(I,L) = ((SECSL-DELT)*OZROW(I,L) + DELT*OZROL(I,L))/SECSL 
  200 CONTINUE
C 
      RETURN
      END 
