      SUBROUTINE ALPDY3X(DALP,ALP,LSR,LM,EPSI,NLAT,IRAM) 
C
C     * OCT 29/03 - M. LAZARE. REVERSE ORDER OF POLYNOMIALS
C     *                        AND DO OVER ALL LATITUDES.
C     * OCT 15/92 - PREVIOUS VERSION ALPDY3.
C     * JUL 14/92 - PREVIOUS VERSION ALPDY2.
C 
C     * SETS DALP TO N-S DERIVATIVE OF LEGENDRE POLYNOMIALS IN ALP. 
C     * EPSI CONTAINS PRECOMPUTED CONSTANTS.
C     * LSR CONTAINS ROW LENGTH ONFO. 
C 
      IMPLICIT REAL*8 (A-H,O-Z),
     +INTEGER (I-N)
      REAL*8 DALP(NLAT,IRAM), ALP(NLAT,IRAM), EPSI(IRAM) 
      INTEGER LSR(2,LM+1)
C-------------------------------------------------------------------- 
      DO 300 M=1,LM 
        MS=M-1
        KL=LSR(2,M) 
        KR=LSR(2,M+1)-2 
        DO 210 K=KL,KR
          FNS=FLOAT(MS+K-KL)
          DO 200 NJ=1,NLAT
            ALPILM=0. 
            IF(K.GT.KL) ALPILM=ALP(NJ,K-1) 
            DALP(NJ,K)=(FNS+1)*EPSI(K)*ALPILM-FNS*EPSI(K+1)*ALP(NJ,K+1) 
  200     CONTINUE
  210   CONTINUE   
C
        DO 220 NJ=1,NLAT  
          DALP(NJ,KR+1)=0. 
  220   CONTINUE
  300 CONTINUE     
C 
      RETURN
      END 
