      SUBROUTINE SPMCON(S,SEXPK,SH,SHEXPK,SF,DS,DEL,FVORT,PI,ILEV)
C 
C     *****   NOV 1975  - JOHN HENDERSON, ROGER DALEY   ***** 
C     * SETS CONSTANTS FOR THE MULTILEVEL SPECTRAL MODEL. 
C     * MODIFIED JUNE 1979 -R.LAPRISE 
C 
      IMPLICIT REAL (A-H,O-Z),
     +INTEGER (I-N)
      DIMENSION S(1),SH(1),SF(1),DS(1),DEL(1) 
      DIMENSION SEXPK(ILEV),SHEXPK(ILEV)
C 
      COMMON/PARAMS/ WW,TW,A,ASQ,GRAV,RGAS,RGOCP,RGOASQ,CPRES 
C-----------------------------------------------------------------------
      ILEVM = ILEV-1
C 
C     *    WW = EARTH ROTATION RATE (1/SEC).
C     *     A = EARTH RADIUS (M). 
C     *  GRAV = GRAVITY ACCELERATION (M/SEC**2).
C     *  RGAS = DRY AIR GAS CONSTANT (JOULE/(KG*DEG)).
C     * RGOCP = RGAS/(DRY AIR SPECIFIC HEAT)
C 
      WW=7.292E-5 
      TW=WW+WW
      A=6.37122E06
      ASQ=A*A 
      GRAV=9.80616E0
      RGAS=287.04E0 
      RGOCP=2.E0/7.E0 
      RGOASQ=RGAS/ASQ 
      CPRES=RGAS/RGOCP
C 
C     * FVORT = VORTICITY OF EARTH ROTATION.
C 
      PI=3.1415926535897E0
      FVORT=TW*SQRT(2.E0/3.E0)
C 
C     *  S = SIGMA AT THE ODD LEVELS. 
C     * SH = SIGMA AT THE EVEN LEVELS 
C     * DS = DELTASIGMA BETWEEN EVEN LEVELS.
C 
      DO 30 IH=1,ILEVM
   30 DEL(IH) = S(IH+1) - S(IH) 
      DEL(ILEV) = 1.E0 - S(ILEV)
C 
      DO 40 IH = 1,ILEVM
   40 SH(IH) = SQRT(S(IH)*S(IH+1))
      SH(ILEV) = SQRT(S(ILEV))
C 
      DS(1) = SH(1) 
      DO 50 IH=2,ILEVM
   50 DS(IH) = SH(IH)-SH(IH-1)
      DS(ILEV) = 1.E0-SH(ILEVM) 
C 
      DO 60 IH=1,ILEVM
   60 SF(IH) = LOG(S(IH+1)/S(IH))
      SF(ILEV) = LOG(1.E0/S(ILEV)) 
C 
      DO 70  L=1,ILEV 
      SEXPK(L)=S(L)**RGOCP
   70 SHEXPK(L)=SH(L)**RGOCP
      RETURN
      END
