      SUBROUTINE LLFXY(DLAT,DLON,X,Y,D60,DGRW,NHEM) 
C 
C     *****   FEB 1975  -  JOHN D. HENDERSON  ****
C     * CALCULATE LATITUDE AND LONGITUDE IN DEGREES OF POINT (X,Y)
C     *  MEASURED FROM THE POLE. (LONGITUDE IS POSITIVE EASTWARD).
C     * GRID IS POLAR STEREOGRAPHIC WITH STANDARD LATITUDE AT 60 DEG. 
C     *  AND GRID SIZE D60 METERS.
C     * ZERO DEGREES LONGITUDE IN THE GRID IS (DGRW) DEGREES
C     *  IN MAP COORDINATES.
C     * NHEM 1 = NORTHERN HEMISPHERE.   NHEM 2 = SOUTHERN HEMISPHERE. 
C     * 1.866025=(1+SIN60),   6.371E+6=EARTH RADIUS IN METERS.
C 
C-----------------------------------------------------------------------
      IMPLICIT REAL (A-H,O-Z),
     +INTEGER (I-N)
      RE=1.866025E0*6.371E+6/D60
      RE2=RE**2 
      C1=180.E0/3.14159E0 
C 
C     * IF POINT IS AT POLE SET COORD TO (0.,90.).
C 
      DLAT=90.E0
      DLON=0.E0 
      IF(X.EQ.0.E0 .AND. Y.EQ.0.E0) GO TO 39
C 
C     * CALCULATE LONGITUDE IN MAP COORDINATES. 
C 
      IF(X.EQ.0.E0) DLON=SIGN(90.E0,Y)
      IF(X.NE.0.E0) DLON=ATAN(Y/X)*C1 
      IF(X.LT.0.E0) DLON=DLON+SIGN(180.E0,Y)
C 
C     * ADJUST LONGITUDE FOR GRID ORIENTATION.
C 
      DLON=DLON-DGRW
      IF(DLON.GT.+180.E0) DLON=DLON-360.E0
      IF(DLON.LT.-180.E0) DLON=DLON+360.E0
C 
C     * CALCULATE LATITUDE. 
C 
      R2=X**2+Y**2
      DLAT=(RE2-R2)/(RE2+R2)
      DLAT= ASIN(DLAT)*C1 
C 
C     * CHANGE SIGNS IF IN SOUTHERN HEMISPHERE. 
C 
   39 IF(NHEM.EQ.2) DLAT=-DLAT
      IF(NHEM.EQ.2) DLON=-DLON
      RETURN
      END 
