      SUBROUTINE SPLAT (A,LI,NC,II,INCR,GMIN,GMAX)
C 
C     * MAR 01/91 - F.MAJAESS (CHANGE DEFAULT TO WRITE VALUE OF FIRST CURVE)
C     * MAY 10/77 - J.D.HENDERSON.
C     * PLOTS UP TO  8 CURVES ON THE SAME GRAPH.
C     * PLOTS EVERY INCR POINTS FROM 1 TO II IN A(LI,NC). 
C     * CURVES USE SYMBOLS A,B,C...ETC. 
C     * VALUE OF LAST CURVE WRITTEN ON X-AXIS IF INCR IS POSITIVE.
C     * NO GRAPH DRAWN IF INCR=0 OR NC=0. 
C     * GRAPH LIMITS GMIN,GMAX AND MIDDLE VALUE PRINTED AT START AND END
C     * IF GMIN=GMAX GRAPH LIMITS ARE CALCULATED FIRST. 
C     * IF THE RANGE IS STILL ZERO, IT IS SET TO 1. 
C 
      IMPLICIT REAL (A-H,O-Z),
     +INTEGER (I-N)
      REAL A(LI,NC) 
      CHARACTER*1 NG(101),S(4),IGR(8) 
      DATA S/' ','I','-','*'/ 
      DATA IGR/ 'A','B','C','D','E','F','G','H'/ 
C---------------------------------------------------------------------
      IF(INCR.EQ.0.OR.NC.LE.0) RETURN 
      INC=ABS(INCR)
      AMIN=GMIN 
      AMAX=GMAX 
C 
C     * COMPUTE GRAPH LIMITS IF REQUESTED.
C 
      IF(AMIN.LT.AMAX) GO TO 14 
      AMIN=A(1,1) 
      AMAX=AMIN 
      DO 12 J=1,NC
      DO 12 I=1,II,INC
      AMIN=MIN(AMIN,A(I,J)) 
      AMAX=MAX(AMAX,A(I,J)) 
   12 CONTINUE
      IF(AMIN.EQ.AMAX) AMAX=AMIN+1.E0 
C 
C     * COMPUTE RANGE AND PRINT Y-AXIS AT START OF PLOT.
C 
   14 RANGE=AMAX-AMIN 
      DA100=100.E0/RANGE
      AX=(AMAX+AMIN)*0.5E0 
      WRITE(6,605) IGR(NC),RANGE
      WRITE(6,610) AMIN,AX,AMAX 
      WRITE(6,615)
C 
C     * LOOP OVER THE X-AXIS VALUES TO BE PLOTTED.
C 
      DO 24 I=1,II,INC
C 
C     * INITIALIZE THE PRINT ROW NG.
C 
      DO 15 K=1,101 
   15 NG(K)=S(1)
      NG(51)=S(2) 
      IF(I/10*10.EQ.I) NG(51)=S(3)
C 
C     * INSERT THE VALUES TO BE PLOTTED INTO NG AND PRINT.
C 
      DO 20 J=1,NC
      Y=(A(I,J)-AMIN)*DA100+1.5E0 
      K=INT(Y)
      IF(K.GE.1.AND.K.LE.101) NG(K)=IGR(J)
   20 CONTINUE
C     IF(INCR.GT.0) WRITE(6,620) I,A(I,NC),NG 
      IF(INCR.GT.0) WRITE(6,620) I,A(I, 1),NG 
      IF(INCR.LT.0) WRITE(6,625) NG 
C 
   24 CONTINUE
C 
C     * RE-WRITE THE Y-AXIS AT THE END OF THE PLOT. 
C 
      WRITE(6,615)
      WRITE(6,610) AMIN,AX,AMAX 
   99 RETURN
C---------------------------------------------------------------------
  605 FORMAT('1 CURVE ',A1,T87,'RANGE =',1PE12.5) 
  610 FORMAT(' ',16X,1PE12.5,T68,E12.5,T118,E12.5)
  615 FORMAT(' ',21X,10('I---------'),'I') 
  620 FORMAT(' ',I4,1PE15.6,2X,101A1) 
  625 FORMAT(' ',21X,101A1) 
      END 
