      SUBROUTINE XYFLL(X,Y,DLAT,DLON,D60,DGRW,NHEM) 
C 
C     * MAR 02/09 - S.KHARIN (USE HIGHER PRECISION "PI"
C     *                       AND "AE" VALUES)
C     *****   FEB 1975  -  JOHN D. HENDERSON  ****
C     * CALCULATES GRID COORDINATES MEASURED FROM THE POLE
C     *        OF POINT (DLAT,DLON) GIVEN IN DEGREES. 
C     *        (LONGITUDE IS POSITIVE EASTWARD).
C     * GRID IS POLAR STEREOGRAPHIC WITH STANDARD LATITUDE AT 60 DEG. 
C     *  AND GRID SIZE D60 METERS.
C     * ZERO DEGREES LONGITUDE IN THE GRID IS (DGRW) DEGREES
C     *  IN MAP COORDINATES.
C     * NHEM 1 = NORTHERN HEMISPHERE.   NHEM 2 = SOUTHERN HEMISPHERE. 
C     * 1.866025=(1+SIN60),   6.37122E+6=EARTH RADIUS IN METERS.
C 
C-----------------------------------------------------------------------
      IMPLICIT REAL (A-H,O-Z),
     +INTEGER (I-N)
      DATA PI/3.14159265358979E0/,AE/6.37122E+6/
      D2R=PI/180.E0 
      RE=(1.E0+SIN(PI/3.E0))*AE/D60
      GLON=DLON 
      IF(NHEM.EQ.2) GLON=-DLON
      GLAT=DLAT 
      IF(NHEM.EQ.2) GLAT=-DLAT
      RLON=D2R*(GLON+DGRW) 
      RLAT=D2R*GLAT
      SINLAT=SIN(RLAT)
      R=RE*SQRT((1.E0-SINLAT)/(1.E0+SINLAT))
      X=R*COS(RLON) 
      Y=R*SIN(RLON) 
      RETURN
      END 
