      SUBROUTINE GGAST2(SC,LSR,LM,LA, GG,ILG1,ILAT,ILEV,SL,WL,
     1                       ALP,EPSI,WRKS,WRKL)
C 
C     * JUL 14/92 - E. CHAN (ADD REAL*8 DECLARATIONS)
C     * JUL 31/79 - J.D.HENDERSON 
C     * PRODUCES GLOBAL SPECTRAL COEFF SET SC(LA,ILEV)
C     * FROM GLOBAL GAUSSIAN GRID SET GG(ILG1,ILAT,ILEV). 
C     * LSR CONTAINS ROW LENGTH INFO FOR ALP,EPSI,SC. 
C     * ALP = WORK FIELD FOR LEGENDRE POLYNOMIALS.
C     * EPSI = PRECOMPUTED CONSTANTS. 
C     * SL = SIN(LATITUDE) OF GAUSSIAN ROWS FROM S.POLE TO N.POLE.
C     * WL = GAUSSIAN WEIGHTS 
C 
C     * LEVEL 2,GG,SC,ALP,EPSI,WRKL 
      IMPLICIT REAL (A-H,O-Z),
     +INTEGER (I-N)
      COMPLEX SC(LA,ILEV) 
      REAL GG(ILG1,ILAT,ILEV),WRKS(1) 
      REAL*8 ALP(1), EPSI(1), SL(1), WL(1)
      COMPLEX WRKL(1) 
      INTEGER LSR(2,1)
C-------------------------------------------------------------------- 
      ILG=ILG1-1
      ILGH=ILG/2
      MAXF=LM-1 
      NP=LSR(1,LM+1)-1
      DO 110 L=1,ILEV 
      DO 110 N=1,NP 
  110 SC(N,L)=(0.E0,0.E0) 
C 
      DO 210 J=1,ILAT 
      CALL ALPST2(ALP,LSR ,LM,SL(J),EPSI) 
C 
      DO 205 L=1,ILEV 
      CALL FFWFG2(WRKL,ILGH,GG(1,J,L),ILG1,MAXF,ILG,WRKS,1) 
      CALL FAST2(SC(1,L),LSR,LM,WRKL,ALP,WL(J)) 
  205 CONTINUE
C 
  210 CONTINUE
      RETURN
      END
