      SUBROUTINE INTGT (GTPAM,GTPAK,GTPAL,GCPAK,GTROW,GTROL,GCROW,
     1                  NPPS,NPGG,LON,LAT,MDAY1,IDAY,MDAY,GG) 
C 
C     * MAY 08/84 - R.LAPRISE.
C     * INTERPOLATE GT FOR DAY=IDAY (INTO GTPAM), BETWEEN 
C     * MDAY1 (INTO GTPAK) AND MDAY (INTO GTPAL) OVER OCEAN.
C     * OVER LAND AND SEA ICE, USE GT FOR MDAY. 
C 
      IMPLICIT REAL (A-H,O-Z),
     +INTEGER (I-N)

      REAL GTPAK(1),GTPAL(1),GCPAK(1),GTROW(1),GTROL(1),GCROW(1)
      REAL GTPAM(1),GG(1) 
C---------------------------------------------------------------------
      DAY1=FLOAT(MDAY1) 
      DAY2=FLOAT(IDAY)
      DAY3=FLOAT(MDAY)
      IF(DAY2.LT.DAY1) DAY2=DAY2+365. 
      IF(DAY3.LT.DAY2) DAY3=DAY3+365. 
      W1=(DAY2-DAY1)/(DAY3-DAY1)
      W2=(DAY3-DAY2)/(DAY3-DAY1)
      WRITE(6,6000) IDAY,MDAY1,MDAY,W1,W2 
C 
C 
      DO 200 J=1,LAT
      CALL UPGR(GCROW,LON,GCPAK,J,NPGG,GG)
      CALL UPGR(GTROW,LON,GTPAK,J,NPPS,GG)
      CALL UPGR(GTROL,LON,GTPAL,J,NPPS,GG)
C 
      DO 100 I=1,LON
C 
C     * OVER OCEAN... 
C 
      IF(ABS(GCROW(I)).LE.0.5)THEN
      GTROW(I)=W1*GTROL(I) + W2*GTROW(I)
C 
C     * OVER LAND OR SEA ICE... 
C 
      ELSE
      GTROW(I)=GTROL(I) 
      ENDIF 
  100 CONTINUE
C 
      CALL PKGR(GTPAM,J,GTROW,LON,NPPS,GG)
  200 CONTINUE
      RETURN
C---------------------------------------------------------------------- 
 6000 FORMAT(' INTERPOLATING FOR', I5, ' BETWEEN', I5, ' AND',
     1       I5, ' WITH WEIGHTS=', 2F7.3)
      END 
