      SUBROUTINE PHSIL2(GTROW,GTROL,GCROW,SICROL,ILG,DELT,DAY,
     1                  LDAY,MDAY,IOCEAN) 
C 
C     * MAY 21/89 - M.LAZARE. - BASED ON PHSIL EXCEPT LDAY,SICROL AND 
C     *                         IOCEAN USED TO INTERPOLATE TO MONTH 
C     *                         BEGINNING IF FIXED-OCEAN AND NEXT 
C     *                         MONTH HAS SEA-ICE COVER (THROUGH MONTH).
C     * GTROW = GROUND TEMPERATURE FOR PREVIOUS TIMESTEP. 
C     * GTROL = GROUND TEMPERATURE AT NEXT PHYSICS TIME.
C     * SICROL= SEA-ICE MASS       AT NEXT PHYSICS TIME.
C     * DAY = CURRENT DAY OF THE YEAR (INCLUDING FRACTION). 
C     * LDAY = DATE OF NEXT FIRST-OF-MONTH PHYSICS. 
C     * MDAY = DATE OF NEXT      MID-MONTH PHYSICS. 
C     * DELT = MODEL TIMESTEP IN SECONDS. 
C 
      IMPLICIT REAL (A-H,O-Z),
     +INTEGER (I-N)

C     * LEVEL 2,GTROW,GTROL,GCROW,SICROL
      REAL GTROW(1),GTROL(1),GCROW(1),SICROL(1) 
C-------------------------------------------------------------------- 
C     * COMPUTE THE NUMBER OF TIMESTEPS FROM HERE TO LDAY,MDAY. 
C 
      FLDAY=FLOAT(LDAY) 
      FMDAY=FLOAT(MDAY) 
      IF(FLDAY.LT.DAY) FLDAY=FLDAY+365. 
      IF(FMDAY.LT.DAY) FMDAY=FMDAY+365. 
      DAYSL=FLDAY-DAY 
      DAYSM=FMDAY-DAY 
      STEPSL=DAYSL*86400./DELT
      STEPSM=DAYSM*86400./DELT
C 
C     * INTERPOLATE NEW GT ONLY OVER SEA (WHERE GC=0.)
C     * IF FIXED-OCEAN AND NEXT MONTH IS SEA-ICE, INTERPOLATE TO
C     * BEGINNING-OF-MONTH WITH TARGET BEING 271.2 (SET AT BEGINNING OF 
C     * PHYSICS), AFTER MID-MONTH ONLY. 
C 
      DO 210 I=1,ILG
        IF(ABS(GCROW(I)).GT..5) GO TO 210 
        IF(IOCEAN.GT.0.OR.SICROL(I).LE.0..OR.FMDAY.LE.FLDAY) THEN 
          GTROW(I) = ((STEPSM-1) * GTROW(I) + GTROL(I)) / STEPSM
        ELSE
          GTROW(I) = ((STEPSL-1) * GTROW(I) + GTROL(I)) / STEPSL
        ENDIF 
  210 CONTINUE
C 
      RETURN
      END 
