      SUBROUTINE GETGC6(NF,GCPAK,NPGG,NLON,NLAT,IDAY,LDAY,GG, 
     1                 KSTART,ICEMOD) 
C
C     * MAY 23/95 - M.LAZARE. INCLUDE OPTION "MYRSSTI" VIA COMMON
C     *                       BLOCK "KEEPTYM", TO DO AMIP-LIKE RUNS. 
C     *                       SIMILARILY OPTION "ISAVDTS" TO SAVE
C     *                       GCM OUTPUT IN "yyyymmddhh" FORMAT.
C     * OCT 11/87 - M.LAZARE. PREVIOUS VERSION GETGC5.
C
C     * REPLACE THE GROUND COVER FIELD IN THE GCM,
C     * WHENEVER A REQUEST IS MADE TO UPDATE THE PHYSICS FIELDS.
C     * THIS WILL HAPPEN AT THE START OF A SIMULATION WHEN KOUNT=0
C     * AND WHEN THE CURRENT DATE (IDAY) REACHES THE NEXT 
C     * PHYSICS DATE (LDAY). IF AN ICE MODEL IS INCLUDED, THEN GROUND 
C     * COVER IS A PROGNOSTIC VARIABLE AND THE CLIMATOLOGICAL VALUES
C     * AREN'T USED AFTER MODEL START-UP. 
C 
      IMPLICIT REAL (A-H,O-Z),
     +INTEGER (I-N)

      REAL GCPAK(1),GG(1) 
      INTEGER NFDM(12)
      COMMON /KEEPTIM/ IYEAR,IYMDH,MYRSSTI,ISAVDTS
      DATA NFDM/1,32,60,91,121,152,182,213,244,274,305,335/ 
C-------------------------------------------------------------------- 
C     * RESET LDAY TO FIRST DAY OF THE NEXT MONTH.
C 
      L=0 
      DO 150 N=1,12 
  150 IF(IDAY.GE.NFDM(N)) L=N+1 
      IF(L.EQ.13) L=1 
      LDAY=NFDM(L)
      WRITE(6,6020) LDAY
C 
C     * GET NEW GROUND COVER.
C     * VALUE TO SEARCH FOR IN IBUF(2) IS DEPENDANT ON WHETHER RUN
C     * IS USING STANDARD BOUNDARY FORCING OR MULTI-YEAR CONDITIONS.
C 
      IF(MYRSSTI.EQ.0)     THEN
        IBUF2=IDAY
      ELSE
        IBUF2=IYMDH
      ENDIF
C
      IF(KSTART.EQ.0 .OR. ICEMOD.EQ.0) THEN 
      CALL GETAGB(GCPAK,NPGG,NC4TO8("  GC"),NF,NLON,NLAT,IBUF2,GG)
      ENDIF 
C 
      RETURN
C-------------------------------------------------------------------- 
 6020 FORMAT('0',3X,' LDAY RESET TO',I6) 
      END
