      SUBROUTINE GGDX2(DX,GG,NLON,NLAT,RAD,CL)
C 
C     * JUL 14/92 - E. CHAN (ADD REAL*8 DECLARATIONS)
C     * NOV 13/80 - J.D.HENDERSON 
C     * SETS GRID DX TO THE LONGITUDE DERIVATIVE OF GRID GG.
C     *    I.E.   1./COS(LAT) * D(GG)/D(LON)
C     * RAD CONTAINS LATITUDES IN RADIANS OF THE ROWS OF GG.
C     * CL CONTAINS THE CORRESPONDING COSINES.
C 
C     * LEVEL 2,DX,GG 
      IMPLICIT REAL (A-H,O-Z),
     +INTEGER (I-N)
      REAL   DX(NLON,NLAT),GG(NLON,NLAT)
      REAL*8 RAD(1),CL(1) 
C-------------------------------------------------------------------- 
      NLONM=NLON-1
      DELD=360.E0/FLOAT(NLONM)
      DELR=2.E0*DELD*(3.14159E0/180.E0) 
C 
C     * COMPUTE THE LONGITUDE DERIVATIVE. 
C     * USE CENTERED DIFFERENCES EVERYWHERE.
C 
      DO 220 J=1,NLAT 
      DELCOS=1.E0/(CL(J)*DELR)
      DO 210 I=2,NLONM
  210 DX(I,J)=(GG(I+1,J)-GG(I-1,J))*DELCOS
      DX(1,J)=(GG(2,J)-GG(NLONM,J))*DELCOS
      DX(NLON,J)=DX(1,J)
  220 CONTINUE
C 
      RETURN
      END 
